Skip to content

Instantly share code, notes, and snippets.

@salfare

salfare/LMIC_RFM_sleep_vcc

Last active September 19, 2018 13:13
Show Gist options

  • Select an option

    Learn more about clone URLs
  • Save salfare/019d77445a533b0a59eaadac7dd4eeea to your computer and use it in GitHub Desktop.

Select an option

Learn more about clone URLs
Save salfare/019d77445a533b0a59eaadac7dd4eeea to your computer and use it in GitHub Desktop.
Download ZIP
Raw
LMIC_RFM_sleep_vcc
/*******************************************************************************
* Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
*
* Permission is hereby granted, free of charge, to anyone
* obtaining a copy of this document and accompanying files,
* to do whatever they want with them without any restriction,
* including, but not limited to, copying, modification and redistribution.
* NO WARRANTY OF ANY KIND IS PROVIDED.
*
* This example sends a valid LoRaWAN packet with static payload,
* using frequency and encryption settings matching those of
* the (early prototype version of) The Things Network.
*
* Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in g1,
* 0.1% in g2).
*
* ToDo:
* - set NWKSKEY (value from console.thethingsnetwork.com)
* - set APPKSKEY (value from console.thethingsnetwork.com)
* - set DEVADDR (value from console.thethingsnetwork.com)
* - optionally comment #define DEBUG
* - optionally comment #define SLEEP
* - set TX_INTERVAL in seconds
*
* alst: added bytes for temp, bat humd and light
* alst: added Arduion VCC read
* alst: added low power library
*
*******************************************************************************/
#include <lmic.h>
#include <hal/hal.h>
#include <SPI.h>
long randNumber = 2;
// LoRaWAN NwkSKey, network session key
//test
// all in msb
static const PROGMEM u1_t NWKSKEY[16] = { 0xAD, 0x9A, 0xA6, 0x67, 0x04, 0xF7, 0x0E, 0xF9, 0xF9, 0x13, 0x09, 0xE0, 0x91, 0xF7, 0xF1, 0x8D } ;
static const u1_t PROGMEM APPSKEY[16] = { 0x00, 0x15, 0x6F, 0x93, 0x98, 0x7E, 0x55, 0xF0, 0x43, 0x0D, 0x15, 0x84, 0x21, 0xA4, 0x38, 0x2A };
static const u4_t DEVADDR = 0x260116B4 ;
// show debug statements; comment next line to disable debug statements
#define DEBUG
// use low power sleep; comment next line to not use low power sleep
#define SLEEP
// Schedule TX every this many seconds (might become longer due to duty
// cycle limitations).
const unsigned TX_INTERVAL = 11;
// temp2, batt2, humm2, light2
byte mydata[8];
int16_t temp = 0;
int16_t batt = 0;
int16_t humd = 0;
int8_t Size = 0;
#ifdef SLEEP
#include "LowPower.h"
bool next = false;
#endif
// These callbacks are only used in over-the-air activation, so they are
// left empty here (we cannot leave them out completely unless
// DISABLE_JOIN is set in config.h, otherwise the linker will complain).
void os_getArtEui (u1_t* buf) { }
void os_getDevEui (u1_t* buf) { }
void os_getDevKey (u1_t* buf) { }
static osjob_t sendjob;
// Pin mapping
const lmic_pinmap lmic_pins = {
.nss = 10,
.rxtx = LMIC_UNUSED_PIN,
.rst = 0,
.dio = {2,5,7}, // 2 5 7 for black board aslt 0.2
};
void onEvent (ev_t ev) {
#ifdef DEBUG
Serial.println(F("Enter onEvent"));
#endif
switch(ev) {
case EV_SCAN_TIMEOUT:
Serial.println(F("EV_SCAN_TIMEOUT"));
break;
case EV_BEACON_FOUND:
Serial.println(F("EV_BEACON_FOUND"));
break;
case EV_BEACON_MISSED:
Serial.println(F("EV_BEACON_MISSED"));
break;
case EV_BEACON_TRACKED:
Serial.println(F("EV_BEACON_TRACKED"));
break;
case EV_JOINING:
Serial.println(F("EV_JOINING"));
break;
case EV_JOINED:
Serial.println(F("EV_JOINED"));
break;
case EV_RFU1:
Serial.println(F("EV_RFU1"));
break;
case EV_JOIN_FAILED:
Serial.println(F("EV_JOIN_FAILED"));
break;
case EV_REJOIN_FAILED:
Serial.println(F("EV_REJOIN_FAILED"));
break;
case EV_TXCOMPLETE:
Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
if(LMIC.dataLen) {
// data received in rx slot after tx
Serial.print(F("Data Received: "));
Serial.write(LMIC.frame+LMIC.dataBeg, LMIC.dataLen);
Serial.println();
}
// Schedule next transmission
#ifndef SLEEP
os_setTimedCallback(&sendjob, os_getTime()+sec2osticks(TX_INTERVAL), do_send);
#else
next = true;
#endif
break;
case EV_LOST_TSYNC:
Serial.println(F("EV_LOST_TSYNC"));
break;
case EV_RESET:
Serial.println(F("EV_RESET"));
break;
case EV_RXCOMPLETE:
// data received in ping slot
Serial.println(F("EV_RXCOMPLETE"));
break;
case EV_LINK_DEAD:
Serial.println(F("EV_LINK_DEAD"));
break;
case EV_LINK_ALIVE:
Serial.println(F("EV_LINK_ALIVE"));
break;
default:
Serial.println(F("Unknown event"));
break;
}
#ifdef DEBUG
Serial.println(F("Leave onEvent"));
#endif
}
void do_send(osjob_t* j){
//Serial.println( readVcc() , DEC);
batt = readVcc();
// here I fill the values as I do not have a sensor connected
float Humd = 66.66;
float Temp = 22.22;
temp = (Temp+40) *100 ;
humd = Humd * 100;
Serial.print("devid: ");
Serial.print(DEVADDR,HEX);
Serial.print(" batt: ");
Serial.print( batt);
Serial.print(" Temperature:");
Serial.print(Temp, 1);
Serial.print("C");
Serial.print(" ");
Serial.print(temp);
Serial.print(" Humidity:");
Serial.print(Humd, 1);
Serial.print("%");
Serial.print(" ");
Serial.print(humd);
Serial.println();
#ifdef DEBUG
Serial.println(F("Enter do_send"));
#endif
pack_data();
// Check if there is not a current TX/RX job running
if (LMIC.opmode & OP_TXRXPEND) {
Serial.println(F("OP_TXRXPEND, not sending"));
} else {
// Prepare upstream data transmission at the next possible time.
//LMIC_setTxData2(1, mydata, sizeof(mydata)-1, 0);
LMIC_setTxData2(2, mydata, sizeof(mydata), 0); // wenn als Byte definiert stimmt die länge nehme ich an
// LMIC_setTxData2(1, mydata, 8, 0); // wenn als Byte definiert stimmt die länge nehme ich an
Serial.println(F("Packet queued"));
}
// Next TX is scheduled after TX_COMPLETE event.
#ifdef DEBUG
Serial.println(F("Leave do_send"));
#endif
}
void pack_data() {
// here my data gets packed
mydata[0] = temp >> 8 ;
mydata[1] = temp & 0xFF;
mydata[2] = batt >> 8;
mydata[3] = batt & 0xFF;
mydata[4] = humd >> 8;
mydata[5] = humd & 0xFF;
Size = sizeof(mydata) ;
Serial.print("Size :");
Serial.println(Size);
}
void setup() {
pinMode(LED_BUILTIN, OUTPUT);
Serial.begin(115200);
// to avoid syncronisation at power down;
Serial.println(F("random sleep "));
randNumber =random(1,8)+6;
delay(randNumber*100);
Serial.println(F("Enter setup"));
#ifdef VCC_ENABLE
// For Pinoccio Scout boards
pinMode(VCC_ENABLE, OUTPUT);
digitalWrite(VCC_ENABLE, HIGH);
delay(1000);
#endif
// LMIC init
os_init();
// Reset the MAC state. Session and pending data transfers will be discarded.
LMIC_reset();
// Set static session parameters. Instead of dynamically establishing a session
// by joining the network, precomputed session parameters are be provided.
#ifdef PROGMEM
// On AVR, these values are stored in flash and only copied to RAM
// once. Copy them to a temporary buffer here, LMIC_setSession will
// copy them into a buffer of its own again.
uint8_t appskey[sizeof(APPSKEY)];
uint8_t nwkskey[sizeof(NWKSKEY)];
memcpy_P(appskey, APPSKEY, sizeof(APPSKEY));
memcpy_P(nwkskey, NWKSKEY, sizeof(NWKSKEY));
LMIC_setSession (0x1, DEVADDR, nwkskey, appskey);
#else
// If not running an AVR with PROGMEM, just use the arrays directly
LMIC_setSession (0x1, DEVADDR, NWKSKEY, APPSKEY);
#endif
// Set up the channels used by the Things Network, which corresponds
// to the defaults of most gateways. Without this, only three base
// channels from the LoRaWAN specification are used, which certainly
// works, so it is good for debugging, but can overload those
// frequencies, so be sure to configure the full frequency range of
// your network here (unless your network autoconfigures them).
// Setting up channels should happen after LMIC_setSession, as that
// configures the minimal channel set.
LMIC_setupChannel(0, 868100000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
// LMIC_setupChannel(1, 868100000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band . for single channel gw
// LMIC_setupChannel(2, 868100000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band . for single channel gw
// for single channel, I uncomment the two lines above and comment channel 1 - 8 below
LMIC_setupChannel(1, 868300000, DR_RANGE_MAP(DR_SF12, DR_SF7B), BAND_CENTI); // g-band
LMIC_setupChannel(2, 868500000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
LMIC_setupChannel(3, 867100000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
LMIC_setupChannel(4, 867300000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
LMIC_setupChannel(5, 867500000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
LMIC_setupChannel(6, 867700000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
LMIC_setupChannel(7, 867900000, DR_RANGE_MAP(DR_SF12, DR_SF7), BAND_CENTI); // g-band
LMIC_setupChannel(8, 868800000, DR_RANGE_MAP(DR_FSK, DR_FSK), BAND_MILLI); // g2-band
// TTN defines an additional channel at 869.525Mhz using SF9 for class B
// devices' ping slots. LMIC does not have an easy way to define set this
// frequency and support for class B is spotty and untested, so this
// frequency is not configured here.
// Disable link check validation
LMIC_setLinkCheckMode(0);
// Set data rate and transmit power (note: txpow seems to be ignored by the library)
// set Datarate to maximum of SF12 in case Gateway can not be reached with SF7,
// Note: this has huge impact on airtime as transmissioon time doubles per every SF
LMIC_setDrTxpow(DR_SF7,14);
// Start job
do_send(&sendjob);
#ifdef DEBUG
Serial.println(F("Leave setup"));
#endif
}
void loop() {
#ifndef SLEEP
os_runloop_once();
#else
extern volatile unsigned long timer0_overflow_count;
if (next == false) {
os_runloop_once();
} else {
int sleepcycles = TX_INTERVAL / 8; // calculate the number of sleepcycles (8s) given the TX_INTERVAL
#ifdef DEBUG
Serial.print(F("Enter sleeping for "));
Serial.print(sleepcycles);
Serial.println(F(" cycles of 8 seconds"));
#endif
Serial.flush(); // give the serial print chance to complete
for (int i=0; i<sleepcycles; i++) {
// Enter power down state for 8 s with ADC and BOD module disabled
LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
// LMIC uses micros() to keep track of the duty cycle, so
// hack timer0_overflow for a rude adjustment:
cli();
timer0_overflow_count+= 8 * 64 * clockCyclesPerMicrosecond();
sei();
}
#ifdef DEBUG
Serial.println(F("Sleep complete"));
#endif
next = false;
// Start job
do_send(&sendjob);
}
#endif
}
long readVcc() {
// Read 1.1V reference against AVcc
// set the reference to Vcc and the measurement to the internal 1.1V reference
#if defined(__AVR_ATmega32U4__) || defined(__AVR_ATmega1280__) || defined(__AVR_ATmega2560__)
ADMUX = _BV(REFS0) | _BV(MUX4) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#elif defined (__AVR_ATtiny24__) || defined(__AVR_ATtiny44__) || defined(__AVR_ATtiny84__)
ADMUX = _BV(MUX5) | _BV(MUX0);
#elif defined (__AVR_ATtiny25__) || defined(__AVR_ATtiny45__) || defined(__AVR_ATtiny85__)
ADMUX = _BV(MUX3) | _BV(MUX2);
#else
ADMUX = _BV(REFS0) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
#endif
delay(5); // Wait for Vref to settle
ADCSRA |= _BV(ADSC); // Start conversion
while (bit_is_set(ADCSRA,ADSC)); // measuring
uint8_t low = ADCL; // must read ADCL first - it then locks ADCH
uint8_t high = ADCH; // unlocks both
long result = (high<<8) | low;
result = 1125300L / result / 10 ; // Calculate Vcc (in mV); 1125300 = 1.1*1023*1000
return result; // Vcc in millivolts neu in centivolt alst hehe
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment