iurysza · November 17, 2023 08:33 · Dec 27, 2020 · Dec 23, 2020
diff --git a/publishing.gradle b/publishing.gradle
@@ -4,7 +4,7 @@ version = "$libraryVersion"
 publishing {
     publications {
         create("main", MavenPublication) {
-            artifactId = decoderArtifactId
+            artifactId = libraryArtifactId
             it.artifact("$buildDir/obfuscated/${libraryArtifactId}-${version}.jar") {
                 builtBy obfuscateArtifact
             }

diff --git a/gradle.properties b/gradle.properties
@@ -0,0 +1,3 @@
+libraryVersion=0.1.0
+libraryArtifactId=kotlin-library
+proguardVersion=7.0.1
diff --git a/proguard.gradle b/proguard.gradle
@@ -0,0 +1,32 @@
+import proguard.gradle.ProGuardTask
+
+buildscript {
+    repositories {
+        jcenter()
+        google()
+    }
+    dependencies {
+        classpath "com.guardsquare:proguard-gradle:$proguardVersion"
+    }
+}
+
+task("obfuscateArtifact", type: ProGuardTask, dependsOn: jar) {
+    description = "Obfuscates source files"
+
+    def artifactName = "$libraryArtifactId-${libraryVersion}.jar"
+    def obfuscatedFolder = "$buildDir/obfuscated"
+
+    injars "$buildDir/libs/$artifactName"
+    outjars "$obfuscatedFolder/$artifactName"
+
+    // For de-obfuscating stack traces later on
+    printseeds "$obfuscatedFolder/seeds.txt"
+    printmapping "$obfuscatedFolder/mapping.txt"
+
+    // dependencies
+    libraryjars "${System.getProperty('java.home')}/lib/rt.jar" //works for java 8
+    libraryjars configurations.runtime
+    libraryjars sourceSets.main.compileClasspath
+
+    configuration files("$projectDir/gradle/configuration.pro")
+}
diff --git a/publishing.gradle b/publishing.gradle
@@ -0,0 +1,54 @@
+group = "com.group"
+version = "$libraryVersion"
+
+publishing {
+    publications {
+        create("main", MavenPublication) {
+            artifactId = decoderArtifactId
+            it.artifact("$buildDir/obfuscated/${libraryArtifactId}-${version}.jar") {
+                builtBy obfuscateArtifact
+            }
+            addLibInfoToPom(it)
+            addDependenciesToPom(it)
+        }
+        create("unobfuscated", MavenPublication) {
+            artifactId = "$libraryArtifactId-unobfuscated"
+            from components["java"]
+            addLibInfoToPom(it)
+        }
+    }
+    repositories {
+        maven {
+            name = "LocalBuild"
+            url = "file://$buildDir/repo"
+        }
+        maven {
+            name = "NexusName"
+            url = "https://nexus/repository/releases/"
+            credentials {
+                username = System.getenv("NEXUS_USERNAME")
+                password = System.getenv("NEXUS_PASSWORD")
+            }
+        }
+    }
+}
+
+
+private addLibInfoToPom(Publication publication) {
+    publication.pom {
+        name = "My obfuscated library"
+        description = "Does stuff that I want to hide"
+    }
+}
+
+private addDependenciesToPom(MavenPublication publication) {
+    publication.pom.withXml {
+        def dependencies = asNode().appendNode("dependencies")
+        configurations.implementation.allDependencies.each { dep ->
+            def depNode = dependencies.appendNode("dependency")
+            depNode.appendNode("groupId", dep.group)
+            depNode.appendNode("artifactId", dep.name)
+            depNode.appendNode("version", dep.version)
+        }
+    }
+}
No results found