Created
March 29, 2026 15:01
-
-
Save ednisley/17ed1234c0cb754e479988073dcba74b to your computer and use it in GitHub Desktop.
OpenSCAD source code: Bobbin unwinding adapter for HQ Sixteen bobbin winder
This file contains hidden or bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| // HQ Sixteen Bobbin Winder - Unwind adapter | |
| // Ed Nisley - KE4ZNU | |
| // 2026-03-27 | |
| include <BOSL2/std.scad> | |
| Layout = "Show"; // [Show,Build] | |
| /* [Hidden] */ | |
| HoleWindage = 0.2; | |
| Protrusion = 0.01; | |
| Gap = 5.0; | |
| $fn=5*3*4; | |
| WallThick = 2.0; | |
| SpoolRodOD = 6.03; // vertical spool rod | |
| Kerf = 0.5; | |
| BobbinRodOD = 6.0 + HoleWindage; // horizontal bobbin rod | |
| BobbinRodDee = 4.95; // … remaining rod | |
| DeeLength = 20.0; // … recess depth | |
| DeeRodCyl = 28.0; // … overall rod length | |
| AdapterOD = BobbinRodOD + 2*WallThick; | |
| AdapterOAH = 1.5*AdapterOD; | |
| AdapterOAL = AdapterOD + DeeLength; | |
| //----- | |
| // Define things | |
| // Surplus-deal 6 mm rod with a lengthy flat on one end | |
| module DeeRod() { | |
| union() { | |
| intersection() { | |
| xcyl(DeeLength + Protrusion,d=BobbinRodOD,anchor=RIGHT); | |
| down((BobbinRodOD - BobbinRodDee)/2) | |
| cuboid([DeeLength + Protrusion,BobbinRodOD,BobbinRodDee],anchor=RIGHT); | |
| } | |
| xcyl(DeeRodCyl,d=BobbinRodOD,anchor=LEFT); | |
| } | |
| } | |
| module Adapter() { | |
| difference() { | |
| union() { | |
| cyl(AdapterOAH,d=AdapterOD,rounding=WallThick/2); | |
| xcyl(AdapterOAL - AdapterOD/2,d=AdapterOD,anchor=LEFT); | |
| } | |
| zcyl(AdapterOAH + 2*Protrusion,d=SpoolRodOD); | |
| cuboid([AdapterOD+2*Protrusion,Kerf,AdapterOAH+2*Protrusion]); | |
| right(AdapterOD/2 + DeeLength + Protrusion) | |
| DeeRod(); | |
| } | |
| } | |
| //----- | |
| // Build it | |
| if (Layout == "Show") { | |
| Adapter(); | |
| color("Green",0.5) | |
| zcyl(3*AdapterOAH,d=SpoolRodOD); | |
| color("Magenta",0.5) | |
| right(AdapterOD/2 + DeeLength + Protrusion) | |
| DeeRod(); | |
| } | |
| if (Layout == "Build") | |
| up(AdapterOD/2 + DeeLength) | |
| yrot(90) | |
| Adapter(); |
Author
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment
More details on my blog at https://softsolder.com/2026/04/02/hq-sixteen-bobbin-winder-adjustment-and-unwind-adapter/